ÜBERBLICK
Um zu prüfen, ob eine Zelle einen bestimmten Text oder eine Zahl enthält, benötigen wir folgende Funktionen SUCHEN, ISTZAHL und WENN. Wenn die Groß- und Kleinschreibung beachtet werden soll, nutzen wir FINDEN anstatt SUCHEN. Alternativ können wir auch die ZÄHLENWENN-Funktion in Kombination mit Wildcards verwenden.
Sie sehen gerade einen Platzhalterinhalt von Standard. Um auf den eigentlichen Inhalt zuzugreifen, klicken Sie auf den Button unten. Bitte beachten Sie, dass dabei Daten an Drittanbieter weitergegeben werden.
FORMEL
=WENN(ISTZAHL (SUCHEN ("Suchkriterium";A1) ); "enthalten"; "nicht enthalten")
FUNKTIONSWEISE DER FORMEL
Hier wird geschaut, ob das „Suchkriterium“ in der Zelle A1 auftaucht. Das Suchkriterium kann ein Wort, ein Text, eine Zahl oder eine andere beliebige Kombination von Zeichen sein.
1) SUCHEN(„Kriterium“;A1) prüft an welcher Stelle sich „Suchkriterium“ in der Zelle A1 befindet. Wir bekommen entweder die Position als Zahl oder wenn es keinen Treffer gab, den #WERT! Fehler zurück.
2) Mit ISTZAHL wandeln wir das Ergebnis in WAHR oder FALSCH um. Zahl = WAHR, #WERT! = FALSCH
3) Diesen Wahrheitswert verbauen wir dann in unserer WENN-Funktion.
ALTERNATIVE MIT BERÜCKSICHTIGUNG VON GROSS- UND KLEINSCHREIBUN
=WENN(ISTZAHL(FINDEN(„Kriterium“;A1));“ja“;“nein“)
ALTERNATIVE MIT DER ZÄHLENWENN-FUNKTION UND WILDCARDS
=WENN(ZÄHLENWENN(A1; "*"&"Suchkriterium"&"*")=1; "enthalten"; "nicht enthalten")
Hier wird geschaut, ob das „Suchkriterium“ in der Zelle A1 auftaucht. Das Suchkriterium kann ein Wort, ein Text, eine Zahl oder eine andere beliebige Kombination von Zeichen sein.
1) ZÄHLENWENN(A1; „Suchkriterium“) zählt, ob das Kriterium in der Zelle A1 auftaucht. Wir bekommen hier entweder 1 (taucht auf) oder 0 (taucht nicht auf) ausgegeben. Hier wird jedoch der gesamte Zellinhalt mit dem Suchkriterium verglichen.
2) Daher benötigen wir hier die Wildcards bzw. Platzhalterzeichen *. Dieses steht für eine beliebige Anzahl von Zeichen. Diese Platzhalter müssen in Anführungszeichen stehen und werden mit dem &-Zeichen mit dem Suchkriterium verkettet.
„*“&“Suchkriterium“&“*“
Wenn das Suchkriterium aus einer anderen Zelle kommt, kommt folgende Schreibweise zum Einsatz.
„*“&B1&“*“
MEHRERE KRITERIEN
=WENN( ANZAHL( SUCHEN( {"Kriterium1";"Kriterium2"};A1) )> 0; "mind. ein Kriterium"; "")
1) SUCHEN können wir auch mit mehreren Kriterien füttern. Entweder schreiben wir diese mit einer geschweiften Klammer als Array direkt in die Formel oder verweisen auf einen Zellbereich.
2) ANZAHL(SUCHEN({„Kriterium1″;“Kriterium2“}
Wir bekommen hier jetzt zwei Ergebniswerte zurück die entweder #WERT! oder Zahlen enthalten. Dies Ergebniswerte zählen wir mit ANZAHL. Im Ergebnis bekommen wir 0, 1 oder 2 zurück.
3) ANZAHL(SUCHEN({„Kriterium1″;“Kriterium2“};A1))>0
Wenn das Ergebnis größer 0 ist, bedeutet dies, dass mind. ein Kriterium gefunden wurde.
3b) ANZAHL(SUCHEN({„Kriterium1″;“Kriterium2“};A1))=2
Wenn das Ergebnis gleich 2 ist, bedeutet dies, dass beide Kriterien gefunden wurden.
ANZAHL WIE VIELE KRITERIEN GEFUNDEN WURDEN AUSGEBEN
=WENN( ANZAHL( SUCHEN( {"Kriterium1"; "Kriterium2"; "Kriterium3"}; A1) ) > 0; ANZAHL( SUCHEN( {"Kriterium1"; "Kriterium2"; "Kriterium3"}; A11) ) & " Kriterien gefunden"; "")
1) Hier suchen wir nach 3 Kriterien und bekommen die Anzahl der Treffer zurück.
2) Diese Trefferanzahl verbauen wir dann im Ergebnistext.
ANZAHL WIE VIELE KRITERIEN GEFUNDEN WURDEN AUSGEBEN – KURZSCHREIBWEISE
=LET( Formel; ANZAHL( SUCHEN( {"Kriterium1"; "Kriterium2"; "Kriterium3"}; A1) ); WENN( Formel> 0; Formel & " Kriterien gefunden"; "") )
1) Hier nutzen wir LET, um doppelte Formelbestandteile zu vermeiden. Dies hat den Vorteil, dass wir die Kriterien nur an einer Stelle anpassen müssen.
PRAXISBEISPIEL ÜBEREINSTIMMUNGSGRAD
In diesem Beispiel weisen wir der Trefferanzahl einen bestimmten Text zu:
0 Treffer = keine Übereinstimmung
1 Treffer = niedrige Übereinstimmung
2 Treffer = mittlere Übereinstimmung
3 Treffer = hohe Übereinstimmung
=LET( Trefferanzahl; ANZAHL( SUCHEN( Kriterien; A1) );
WENN( Trefferanzahl > 0; WAHL( Trefferanzahl; "niedrige"; "mittlere"; "hohe") & " Übereinstimmung"; "keine Übereinstimmung") )
1) SUCHEN(Kriterien;A1)
Hier suchen wir nach mehreren Kriterien. Das können z.B. Vorname, Nachname, Geburtsdatum usw. sein die in einer Suchmaske bzw. verschiedenen Zellen stehen.
2) LET(Trefferanzahl;ANZAHL(SUCHEN(Kriterien;A1));…
Mit LET speichern wir die Anzahl der Treffer in der Variable Trefferanzahl, welche wir im Rest der Formel verwenden.
3) WENN(Trefferanzahl>0;…
Wenn wir Treffer haben, soll abhängig von der Anzahl der übereinstimmenden Kriterien unterschiedlicher Text zurückgegeben werden.
4) WAHL(Trefferanzahl;“niedrige“;“mittlere“;“hohe“)
Mit der WAHL-Funktion weisen wir abhängig von der Trefferanzahl unterschiedliche Worte zu.
Trefferanzahl 1 = „niedrige“
Trefferanzahl 2 = „mittlere“
Trefferanzahl 3 = „hohe“
und verketten diese mit weiterem Text &“ Übereinstimmung“
5) Wenn die Trefferanzahl gleich null ist, geben wir am Ende der WENN-Funktion noch „keine Übereinstimmung“ aus.
EXCEL & POWER BI ONLINE TRAINING
Schritt für Schritt Excel lernen und mit Pivots, Power-Query, Power-Pivot, Makros & VBA Zeit bei der Arbeit mit Excel einsparen!
Sie sehen gerade einen Platzhalterinhalt von Facebook. Um auf den eigentlichen Inhalt zuzugreifen, klicken Sie auf die Schaltfläche unten. Bitte beachten Sie, dass dabei Daten an Drittanbieter weitergegeben werden.
Sie sehen gerade einen Platzhalterinhalt von Instagram. Um auf den eigentlichen Inhalt zuzugreifen, klicken Sie auf die Schaltfläche unten. Bitte beachten Sie, dass dabei Daten an Drittanbieter weitergegeben werden.
Verwandte Artikel
Hast du eine Frage zu diesem Artikel?
Schreib uns – wir antworten in der Regel innerhalb eines Werktages.